View source for SPARQL query service/queries/examples/en


__TOC__

== <!--T:9--> Basic functions ==

=== <!--T:708--> select - where: Select all items where the author is Tiphaigne de la Roche ===

<!--T:708-->
SELECT all the items and their labels WHERE the author is Tiphaigne de la Roche 

{{SPARQL|query=#title:novels by Tiphaigne de la Roche, with labels
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 

SELECT ?item ?itemLabel
WHERE 
{
  ?item mmdt:P2 mmd:Q2. # item is instance of literary work
  ?item mmdt:P5 mmd:Q940. # item has author Tiphaigne de la Roche
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:708--> Bind: Publication years of the novels ===

<!--T:708-->
Retrieve the publication years of the novels.

{{SPARQL|query=#title:Publication years of the novels
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?work ?workLabel ?year  #display work as Link, the Label and the year
WHERE
{
   ?work mmdt:P2 mmd:Q2.
   ?work mmdt:P9 ?pubyear . # P9 : date of publication
   ?work rdfs:label ?workLabel . # get the label of your item (work)
   FILTER(lang(?workLabel) = "fr") . # filter the language, otherwise you will get triple the amount of results
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   BIND(YEAR(?pubyear) as ?year). # extract the year of the datetime-formatted ?pubyear and bind it to ?year
}

ORDER BY ?year # sort the results by ascending (default) year

}}

=== <!--T:708--> Count: Count all novels per author ===
<!--T:708-->
This query counts all novels per authors within the MiMoTextBase.

{{SPARQL|query=#title:count of written novels per author
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?authorName (count (?authorName) as ?count)
WHERE {
  ?work mmdt:P2 mmd:Q2. # item is instance of literary work
   ?work mmdt:P5 ?author . # work has author.
   ?author rdfs:label ?authorName . # get author label (not only URL to author)
   FILTER(LANG(?authorName) = "en") # other options: "fr", "de". Filter is needed as there is more than one label (language dependent)
}

group by ?authorName
order by desc (?count)

}}

=== <!--T:708--> Limit: Authors and their count of novels limited to top 10 ===
Authors and novels limited to top 10
<!--T:708-->
This query takes all items whose value of {{P|31}} is {{Q|5}} and count the total number of items using COUNT function.


{{SPARQL|query=#title:Authors and their count of novels limited to top 10
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?authorName (count (?authorName) as ?count)
WHERE {
  ?work mmdt:P2 mmd:Q2. # item is instance of literary work
   ?work mmdt:P5 ?author . # work has author.
   ?author rdfs:label ?authorName . # get author label (not only Link to author)
   FILTER(LANG(?authorName) = "en") . # other options: "fr", "de". Filter is needed as there is more than one label (language dependent)
}

group by ?authorName
order by desc (?count)
limit 10
}}

=== <!--T:708--> Filter: Filter for all authors that published a novel in 1800 ===

<!--T:708-->
Filter for all authors that published a novel in 1800

{{SPARQL|query=#title:authors that published a novel in 1800
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT DISTINCT ?authorName (YEAR(?pubdate) as ?year)
WHERE {
  ?work mmdt:P2 mmd:Q2; # item is instance of literary work
        mmdt:P5 ?author; # item has author
        mmdt:P9 ?pubdate. # work has a publication date
  ?author rdfs:label ?authorName . # get author label
  FILTER(LANG(?authorName) = "en"). # other options: "fr", "de". Filter is needed as there is more than one label (language dependent)
  FILTER(YEAR(?pubdate) = 1800). # filter for the publication date of interest
}

}}

=== <!--T:708--> Filter: Get all authors with names containing “beau” ===
Get all authors with names containing “beau”

#title:Authors  whose name contains "beau"
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

{{SPARQL|query=#title:Authors  whose name contains "beau"
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?authorName ?author
WHERE {
  ?author mmdt:P11 mmd:Q11 . # item has property "occupation"(P11) namely "author"(Q11).
  ?author rdfs:label ?authorName . # get author label (not only URL to author)
  FILTER(LANG(?authorName) = "fr") .
  FILTER(CONTAINS(LCASE(?authorName), "beau")).
}
}}

=== <!--T:708--> Optional: Novels by François-Thomas-Marie de Baculard d’ARNAUD and their tonality if available ===

<!--T:708-->
Get all novels written by François-Thomas-Marie de Baculard d’ARNAUD and their tonality
{{SPARQL|query=#title:Novels by François-Thomas-Marie de Baculard d’ARNAUD
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?work ?workLabel ?tonality 
WHERE
{
  ?work mmdt:P5 mmd:Q68 # work has author François-Thomas-Marie de Baculard d’ARNAUD  
  OPTIONAL { ?work mmdt:P31 ?tonality. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

}}

=== <!--T:708--> Get all MiMoText items that have matches to wikidata ===

<!--T:708-->
Example on how to use the "Close Match" or "Exact Match" properties to query the MiMoText database.

{{SPARQL|query=#title:Items with a close match to other knowledge graphs
#defaultView:Dimensions
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT
   ?item ?itemLabel ?value 
WHERE
{
  ?item mmdt:P16 ?value #items with property "close match“, substitute mmdt:P13 for exact match, other relational properties see Wiki
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:708--> Handling of missing data statements concerning unknown narrative form  ===

<!--T:708-->
Example of handling missing data

{{SPARQL|query=#Handling of missing data statements
#title:Handling missing data

# Prefix declarations for shortening URIs
prefix mmd: <http://data.mimotext.uni-trier.de/entity/>
prefix mmdt: <http://data.mimotext.uni-trier.de/prop/direct/> 

# Selecting distinct data fields for analysis
SELECT DISTINCT ?item ?itemLabel ?narrformLabel ?normalizedLabel WHERE {
  ?item mmdt:P2 mmd:Q2. 

  # Optional data fields for more details (some novels may not have these)
  OPTIONAL { ?item mmdt:P33 ?narrform. } # narrative form

  # Handling cases where narrpers is not available
  BIND(if(bound(?narrform), ?narrform, "unknown") as ?normalized)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

== <!--T:9--> Overview over the Graph ==


=== <!--T:708--> Count of authors, novels, thematic and spatial concepts as most important item classes ===

<!--T:708-->
Overview over the numbers of the most important item types that is novels, authors, thematic concepts and spatial concepts.

{{SPARQL|query=#title:count of authors, novels, thematic concepts and spatial concepts
#Query to retrieve the count of authors, novels, thematic concepts and spatial concepts within the MiMoTextBase
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
SELECT ?subject (COUNT(?o) as ?counts)
WHERE {
  VALUES (?p ?o) { (mmdt:P2 mmd:Q2) (mmdt:P11 mmd:Q11) (mmdt:P2 mmd:Q20) (mmdt:P2 mmd:Q26) }
  ?item ?p ?o.
  BIND(IF(?o = mmd:Q2, "novels", 
          IF(?o = mmd:Q11, "authors",
             IF(?o = mmd:Q20, "thematic concepts",
               IF(?o = mmd:Q26, "spatial concepts", "none")
           )
          )
         ) as ?subject)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}GROUP BY ?o ?subject
}}

=== <!--T:708--> List all Properties ===

<!--T:708-->
This shows how to list all properties defined in the database.

{{SPARQL|query=#title:List of all properties used in the MiMoText graph
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?property ?propertyLabel ?prop
WHERE {
    ?property a wikibase:Property . 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
    BIND(STRAFTER(STR(?property), "entity/") as ?prop)
}
ORDER BY ASC(xsd:integer(STRAFTER(STR(?property), 'P')))
}}

=== <!--T:708--> Overview over literary works, their authors, years of publication, tonality etc. based on string statements extracted from the BGRF ===

{{SPARQL|query=#title:Query to retrieve some data about the MiMoTextBase such as Authors, Novels, publicationyears, tonality etc. based on the string statements
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?bgrf ?item ?itemLabel ?authorLabel ?date ?narrpers ?tonality ?pages ?dist_format WHERE {
  ?item mmdt:P2 mmd:Q2. #item is instance of literary work
  OPTIONAL { ?item mmdt:P5 ?author} #item has author (optionally)
  OPTIONAL { ?item mmdt:P4 ?title} #item has title (optionally)
  OPTIONAL { ?item mmdt:P22 ?bgrf}  #item has identifier in the bibliographic metadata? (optionally)
  OPTIONAL { ?item mmdt:P23 ?date} #item has publication date (optionally)
  OPTIONAL { ?item mmdt:P27 ?narrpers} #item has narrative form (optionally)
  OPTIONAL { ?item mmdt:P31 ?tonality} #item has tonality (optionally)
  OPTIONAL { ?item mmdt:P25 ?pages} #item has page information (optionally)
  OPTIONAL { ?item mmdt:P26 ?dist_format} #item has distribution format (optionally)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], fr". }
} ORDER BY ?itemLabel
}}

=== <!--T:708--> Overview over our controlled vocabulary ===

<!--T:708-->
Get an overview of the controlled vocabularies created and used in the project.

{{SPARQL|query=#title:Overview over controlled vocabularies
# Query to retrieve the different controlled vocabularies
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?voc ?vocLabel (COUNT(?vocLabel) as ?count) (COUNT(?wikimatch) as ?wikimatch)
WHERE {
   ?item mmdt:P37 ?voc.
   ?voc mmdt:P2/mmdt:P1 mmd:Q17.
   OPTIONAL{
     values ?wiki {mmdt:P13 mmdt:P16}
     ?item ?wiki ?wikimatch}
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
GROUP BY ?voc ?vocLabel
ORDER BY DESC(?count)
}}

== <!--T:9--> Authors ==

=== <!--T:708--> Timeline: authors and their novels on a timeline by publication date ===


<!--T:708-->
This query finds and displays the first 100 authors found in the database in a timeline.

{{SPARQL|query=#title:Authors on a timeline, limited to 100 results
#defaultView:Timeline{"hide":["?date"]}
#line above necessary to display results in a time line! 
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
Select ?authorlabel ?titel (YEAR(?date) as ?year) ?date 
where{
 ?item mmdt:P2 mmd:Q2;
       mmdt:P5 ?author;
       mmdt:P9 ?date;
       mmdt:P4 ?titel .
 ?author rdfs:label ?authorlabel .
 FILTER(lang(?authorlabel) = "fr") .
 SERVICE wikibase:label {bd:serviceParam wikibase:language "en".}
}LIMIT 100 
}}

=== <!--T:708--> Authors with most novels published (top 20) ===

<!--T:708-->
Get the twenty authors that have written the most novels that are within the MiMoTextBase

{{SPARQL|query=#title:Authors with most novels published (top 20)
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?authorName (count (?authorName) as ?count)
WHERE {
   ?work mmdt:P5 ?author . # work has author.
   ?author rdfs:label ?authorName . # get author label (not only Link to author)
   FILTER(LANG(?authorName) = "en") # other options: "fr", "de". Filter is needed as there is more than one label (language dependent)
 } 
group by ?authorName
order by desc (?count)
limit 20
}}

=== <!--T:708--> Timeline of authors, their Wikidata matches and birth dates ===

<!--T:708-->
This shows the authors and their birth dates on a timeline using federated queries.

{{SPARQL|query=#title:Timeline of authors, their Wikidata matches and birth dates 
#defaultView:Timeline
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata prefix definition for entity
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata prefix definition for property
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> #mimotext prefix for entity is wd
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> #mimotext prefix for property is wdt
Select ?author ?authorLabel ?wikiLink ?birth ?image 
{
  ?author mmdt:P11 ?occupation.
  ?author mmdt:P13 ?wikiLink.
  ?author rdfs:label ?authorLabel
  Filter(lang(?authorLabel) = "en")
          
  SERVICE <https://query.wikidata.org/sparql> {
    ?wikiLink wdt:P569 ?birth. 
 OPTIONAL{   ?wikiLink wdt:P18 ?image.}

  }          
}
}}

== <!--T:9--> Novels ==

=== <!--T:708--> Novels per Author ===

<!--T:708-->
This query shows how to extract authors who have written more than 10 novels. See comments on how to modify this query to extract every author and how many novels they have written in general.

{{SPARQL|query=#title:Authors with more than 10 novels
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/> 
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?authorName (count (?authorName) as ?count)
WHERE {
   ?work mmdt:P5 ?author . # work has author.
   ?author rdfs:label ?authorName . # get author label (not only URL to author)
   FILTER(LANG(?authorName) = "en") # other options: "fr", "de". Filter is needed as there is more than one label (language dependent)
} 

group by ?authorName
having (count(?authorName) > 10) #can be left out to get count of written novels per author a limit can be added eg limit 20
order by desc (?count)

}}

=== <!--T:708--> Publication Years ===

<!--T:708-->
This query shows how to query the publication year of the novels in the database. Keep in mind, that this (and other) information is presented in three different languages ("en", "de", "fr") in the database, it is very important to filter the results using one of them.

{{SPARQL|query=#title:Publication years of the novels
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?work ?workLabel ?year  #display work as Link, the Label and the year
WHERE
{
   ?work mmdt:P2 mmd:Q2. # item is instance of literary work
   ?work mmdt:P9 ?pubyear . # P9 : date of publication
   ?work rdfs:label ?workLabel . # get the label of your item (work)
   FILTER(lang(?workLabel) = "fr") . # filter the language, otherwise you will get triple the amount of results
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   BIND(YEAR(?pubyear) as ?year). # extract the year of the datetime-formatted ?pubyear and bind it to ?year
}

ORDER BY ?year # sort the results by ascending (default) year
}}

=== <!--T:709--> Narrative Perspective ===

<!--T:70-->
This query is for displaying the different narrative perspectives present in the database in a Bar Chart. See comments for querying the narrative perspective of each individual novel.

{{SPARQL|query=#title:Narrative perspectives of the novels
#defaultView:BarChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT (count(?narrativePerspectiveLabel) as ?count) ?narrativePerspectiveLabel 
WHERE
{
  ?work mmdt:P2 mmd:Q2. # item is instance of literary work
  ?work mmdt:P33 ?narrativePerspective. # work (novel) has property P33 (narrative perspective)
  ?narrativePerspective rdfs:label ?narrativePerspectiveLabel. # using of rdfs:label to display labels
  
  FILTER(lang(?narrativePerspectiveLabel) = "en") # filter is neccessary to display only one occurence. Other possibilites would be "en" or "de".
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
 
}group by ?narrativePerspectiveLabel
}}

=== <!--T:709--> Distribution Formats ===

<!--T:709-->
This shows how to display the different distribution formats and how many novels have this property in a Bar Chart.

{{SPARQL|query=#title:Distribution formats of publications
#defaultView:BarChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
Select  (str(SAMPLE(year(?date))) as ?year) (count(?format) as ?count) ?format 
   WHERE{
   ?item mmdt:P26 ?format.
   ?item mmdt:P9 ?date .
  FILTER(lang(?format) = "fr")
# FILTER(lcase(?format) = "12-in"@fr)
      Filter (regex(lcase(?format), "in-\\d+[\\s\\S]"))
   BIND(str(year(?date)) as ?year)
   SERVICE wikibase:label {bd:serviceParam wikibase:language "en" .}
  }

GROUP BY ?format ?year ?count
#having (?count> 2)
}}

=== <!--T:709--> Narrative Locations ===

<!--T:709-->
This queries the different narrative locations that are present in the database.

{{SPARQL|query=#title:Distinct narrative locations in the corpus
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
SELECT  DISTINCT ?locLabel ?loc # use distinct to get all results only one time
 WHERE 
 {
    ?work mmdt:P32 ?loc . 
    ?loc rdfs:label ?locLabel .
   FILTER (LANG(?locLabel) = "en").
 }
 ORDER BY ?locLabel
}}

=== <!--T:709--> Tone of the novels shown as a TreeMap ===

<!--T:709-->
This shows the tone of each novel present in the database in a Tree Map. 
{{SPARQL|query=#title:Tone of the novels
#defaultView:TreeMap
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT
  ?tonality ?itemLabel
WHERE
{
  ?item mmdt:P31 ?tonality. #tonality        
  ?item mmdt:P9 ?date. 
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:709--> Count all novels by year of first Publication ===

<!--T:709-->
This shows how to extract the first publication dates of all French novels in the database and group the results per year.

{{SPARQL|query=#title:First publication dates of all French novels 1751-1800
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT (str(SAMPLE(year(?date))) as ?year) (COUNT(*) AS ?count)
WHERE {
   ?item mmdt:P2 mmd:Q2.
   ?item mmdt:P9 ?date .
}
GROUP BY ?date
ORDER BY DESC(?date) 
}}

=== <!--T:709--> Narrative locations of epistolary novels  ===

<!--T:709-->
This shows how to get the narrative location of epistolary novels.

{{SPARQL|query=#title:Settings of epistolary novels
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?narr_loc_name (count(*) as ?count) where {
  ?item mmdt:P33 mmd:Q42; # get novels that have narrative form "epistolary"
        mmdt:P32 ?narrative_location .
  ?narrative_location rdfs:label ?narr_loc_name .
  filter(lang(?narr_loc_name) = "en")
}

group by ?narr_loc_name
order by desc(?count)

#defaultView:BubbleChart
}}

=== <!--T:709--> Dimension View: Token Count of the novels and their narrative Form  ===

<!--T:709-->
This shows the dimension (or relation) between token count and narrative form.

{{SPARQL|query=#title:Dimension between token count and narrative form
#defaultView:Dimensions
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?tokencount ?formLabel WHERE {
  ?novel mmdt:P40 ?tokencount.
  ?novel mmdt:P33 ?form.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

== <!--T:9--> Themes ==

=== <!--T:709--> Show all thematic concepts within the MiMoTextBase as a BubbleChart and count their occurrences ===

<!--T:709-->
This query shows how to get a list of all themes  with their corresponding QID and occurence.

{{SPARQL|query=#title:List of all themes with corresponding Q-identifier & occurrence 
#defaultView:BubbleChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
SELECT  ?theme
        (sample(?themeLabel) as ?name)
        (count(*) as ?count) 
WHERE {
  ?item mmdt:P2 mmd:Q2.
  ?item mmdt:P36 ?theme. # item is about a topic
  ?theme rdfs:label ?themeLabel .
  FILTER (LANG(?themeLabel) = "en").
}
GROUP BY ?theme
ORDER BY DESC(?count)
}}


=== <!--T:709--> Query Specific Theme that authors wrote about: sentimentalism ===

<!--T:709-->
View all authors who wrote novels about a specified theme in a Bubble Chart.

{{SPARQL|query=#title:Authors with novels about sentimentalism
#defaultView:BubbleChart
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/> 
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?name (COUNT(*) as ?count) WHERE {
  ?item mmdt:P2 mmd:Q2;
        mmdt:P36 mmd:Q3085 ; # item is about sentimentalism
        mmdt:P5 ?author .
  ?author rdfs:label ?name . 
  FILTER(lang(?name) = "en")
}
GROUP BY ?name
ORDER BY DESC (?count)
}}

=== <!--T:709--> Show all places of publications of novels that are about travel ===

<!--T:709-->
View all publication places of novels about a specified theme in a World Map.

{{SPARQL|query=#title:Publication places of novels about "travel"
#defaultView:Map{"hide": ["?nar_loc", "?topic"], "layer": "?themeLabel"}
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata wd
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata wdt

SELECT DISTINCT ?item ?itemLabel ?placeOfPub ?placeOfPubLabel ?wikidataEntityLink ?coordinateLocation ?theme ?themeLabel WHERE {
  ?item mmdt:P36 mmd:Q3126.  # about travel
  ?item mmdt:P36 ?theme.    # work with 0 or more topics
  ?item mmdt:P10 ?placeOfPub.  # work has place publication
  ?placeOfPub mmdt:P13 ?WikiLink.  # place of publication ist mit Wikidata-Link verknüpft
  #Federated Query -> Wikidata
  SERVICE <https://query.wikidata.org/sparql> {
    ?WikiLink wdt:P625 ?coordinateLocation .
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
  }
}
}}


=== <!--T:709--> Get the topics of all novels that have the narrative location rural area===

<!--T:709-->
This shows how to extract themes from the database given a specific narrative location (here: [https://data.mimotext.uni-trier.de/wiki/Item:Q3243 rural area]).

{{SPARQL|query=#title:Themes of novels set in "rural areas"
#defaultView:TreeMap
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/> 
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 

SELECT ?theme ?themeLabel ?item ?itemLabel WHERE {
  ?item mmdt:P2 mmd:Q2.
  ?item mmdt:P36 ?theme .
  ?item mmdt:P32 mmd:Q3243 # items with narrative location (P32): rural area
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:709--> Themes occuring in novels of intention satire ===

<!--T:709-->

{{SPARQL|query=#title:Themes occuring in novels of intention satire
#defaultView:BubbleChart
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>
SELECT ?theme (SAMPLE(?themeLabel) as ?name)  (count(*) as ?count)
WHERE {
  ?item mmdt:P2 mmd:Q2; # item is instance of literary work
        mmdt:P39 mmd:Q3906; #novel has intention satire
        mmdt:P36 ?theme. #novel has theme
      ?theme rdfs:label ?themeLabel .
      FILTER (LANG(?themeLabel) = "en") .
}
GROUP BY ?theme
ORDER BY DESC(?count)
}}

== <!--T:9--> Spaces ==

=== <!--T:709--> Places of publication over the time as a barchart ===

<!--T:709-->

{{SPARQL|query=#title:Change of publication places over time
#defaultView:BarChart
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?year ?placelabel (COUNT(*) as ?countyearplace) WHERE {
  ?item mmdt:P10 ?place.
  ?place rdfs:label ?placelabel .
  ?item mmdt:P9 ?date .
  FILTER(lang(?placelabel) = "fr")
  BIND(str(year(?date)) as ?year)
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" .}
}

GROUP BY ?year ?placelabel
HAVING (?countyearplace > 1)
}}

=== <!--T:709--> Publication Places on a Map using federated queries ===

<!--T:709-->

{{SPARQL|query=#title:Most common publication places
#defaultView:Map{"hide": ["?pub_loc"]}
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata wd
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata wdt

SELECT DISTINCT ?item ?itemLabel ?pub_loc ?pub_locLabel ?wikidataEntityLink ?coordinateLocation ?theme ?themeLabel WHERE {
  ?item mmdt:P10 ?pub_loc.
  ?pub_loc mmdt:P13 ?WikiLink.
  #Federated Query -> Wikidata
  SERVICE <https://query.wikidata.org/sparql> {
    ?WikiLink wdt:P625 ?coordinateLocation
  }      
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
  }
}}

== <!--T:9--> Federated queries ==

=== <!--T:709--> Narrative locations, their Wikidata matches and geographic coordinates ===

<!--T:709-->
This query shows how to display the narrative (or publication) locations using the world map by extracting coordinate locations from Wikidata. Every time information from Wikidata is required, a federated query is necessary. Optionally, an added layer of token count can be added.

{{SPARQL|query=#title:Narrative places (using Wikidata coordinate locations)
#defaultView:Map{"hide": ["?nar_loc"], "markercluster":"true"}
#remove {"hide": ["?nar_loc"], "markercluster":"true"} if publication locations are queried
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata wd
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata wdt
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT DISTINCT ?item ?itemLabel ?nar_loc ?nar_locLabel ?WikiDataEntity ?coordinateLocation
WHERE { ?item mmdt:P32 ?nar_loc. # change mmdt:P10 if publication locations are of interest
  ?nar_loc mmdt:P13 ?WikiDataEntity.
  #Federated Query -> Wikidata
  SERVICE <https://query.wikidata.org/sparql> {
    ?WikiDataEntity wdt:P625 ?coordinateLocation
  }           
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
}}

=== <!--T:709--> Authors and their images using federated query to wikidata ===

<!--T:709-->
This query shows pictures of authors that are present in the MiMoText base and in Wikidata.

{{SPARQL|query=#title:Authors in the MiMoTextBase with exact Wikidata match and Wikidata image
#defaultView:ImageGrid
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 

SELECT ?author ?authorLabel ?img
WHERE {
  ?author mmdt:P11 mmd:Q11;
          mmdt:P13 ?wikiLink.
  SERVICE <https://query.wikidata.org/sparql>{
  ?wikiLink wdt:P18 ?img.
  } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:709--> Get all label entries for "Voltaire" in wikidata as a federated query ===

<!--T:709-->
The entrypoint is the Item for Voltaire within the MiMotextBase. Get all labels availale in wikidata.

{{SPARQL|query=#title:Labels entered on wikidata-entry 'Voltaire'
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT (LANG(?VoltaireLabels) as ?lang) ?VoltaireLabels 
WHERE { 
  
  mmd:Q981 mmdt:P13 ?wikiDataEntity. # Voltaire has a wikidata match.

  #Federated Query -> Wikidata
  SERVICE <https://query.wikidata.org/sparql> {
  ?wikiDataEntity rdfs:label ?VoltaireLabels.
  }      	 
}
ORDER BY ?lang
}}


=== <!--T:709--> Retrieve all novels within the MiMoTextBase that have a URL to the Biliothèque nationale de France ===

<!--T:709-->

{{SPARQL|query=# MiMoText novels with URL to Bibliothèque nationale de France 
#defaultView:ImageGrid
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata prefix definition for entity
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata prefix definition for property
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/> #mimotext prefix for entity is wd
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> #mimotext prefix for property is wdt

SELECT ?item ?itemLabel ?wikidata ?bnfurl ?image 
WHERE {
  ?item mmdt:P2 mmd:Q2.
  ?item mmdt:P13 ?wikidata.
  ?item rdfs:label ?itemLabel .
  FILTER(lang(?itemLabel) = "en")
  SERVICE <https://query.wikidata.org/sparql> {
    ?wikidata wdt:P268 ?bnfid.
    OPTIONAL{ ?wikidata wdt:P18 ?image.}
   OPTIONAL{ wd:P268 wdt:P1630 ?formatterurl.}
   BIND(IRI(REPLACE(?bnfid, '^(.+)$', ?formatterurl)) AS ?bnfurl).
  }         
}
}}

== <!--T:9--> Change over time ==

=== <!--T:709--> Display change of narrative forms over Time ===

<!--T:709-->
This query will show changes in narrative forms in a Bar Chart.

{{SPARQL|query=#title:Change of narrative forms over time 
#defaultView:BarChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
#defaultView:BarChart
Select  (str(SAMPLE(year(?date))) as ?year) (count(?formLabel) as ?count) ?formLabel 
   WHERE{
   ?item mmdt:P33 ?form.
   ?form rdfs:label ?formLabel .
   ?item mmdt:P9 ?date .
   FILTER(lang(?formLabel) = "en")
   BIND(str(year(?date)) as ?year)
   SERVICE wikibase:label {bd:serviceParam wikibase:language "en".}
  }

GROUP BY ?formLabel ?year ?count

}}

=== <!--T:709--> Evolution of "travel" theme in French novels 1751-1800 as relative frenquency ===

<!--T:709-->
This query will display the changes in a specific theme (here: travel) over time in a Bar Chart.

{{SPARQL|query=#title:Evolution of "travel" theme in French novels 1751-1800
#defaultView:BarChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/> 
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
SELECT ?date ?countTravel ?countAll (?countTravel / ?countAll AS ?rel)
WHERE {
 {  
   # Subquery to count novels with the "travel" theme
    SELECT ?date (count(*) AS ?countTravel)
    WHERE {
      ?item mmdt:P9 ?date;
            mmdt:P36 ?topic .
      ?topic rdfs:label ?topicLabel .
      # Filtering for English labels with "travel"
      FILTER(lang(?topicLabel) = "en")
      FILTER(lcase(?topicLabel) = "travel"@en)
    }
    GROUP BY ?date
  }
  {
    # Subquery to count all novels
   SELECT ?date (count(*) AS ?countAll)
   WHERE {
     ?item mmdt:P9 ?date;
         mmdt:P36 ?topic . 
     ?topic rdfs:label ?topicLabel .
     filter(lang(?topicLabel) = "en")
   }
   GROUP BY ?date
 }
}
}}

== <!--T:9--> Comparing sources ==

=== <!--T:709--> Topics of novels that are referenced by both Topic Modeling and bibliographic metadata  ===

<!--T:709-->

{{SPARQL|query=#title:Thematic statements derived from ‘topic modeling’ and the bibliography
#Statements on consistent topics in novels from both sources: Topic Modeling & bibliographic metadata
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
PREFIX mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
PREFIX mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>
PREFIX mmp: <http://data.mimotext.uni-trier.de/prop/>

SELECT DISTINCT ?novel ?novelLabel ?topicLabel ?BGRF_plot_theme WHERE
{   
    ?novel mmp:P36 ?statement.
    ?statement mmps:P36 ?topic.
    ?statement prov:wasDerivedFrom/mmpr:P18 ?tm. #reference statement uses 'P18'='stated in' topic modeling
    ?tm mmdt:P2 mmd:Q18.
    ?statement prov:wasDerivedFrom/mmpr:P18 mmd:Q1. #reference statement uses 'P18'='stated in' bibliographie  
    ?novel mmdt:P30 ?BGRF_plot_theme. #statement in the BGRF about the plot theme.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

=== <!--T:709--> Get all works and authors in which Topic and Topic interest match  ===

<!--T:709-->

{{SPARQL|query=#title:Get all works and authors in which Topic and Topic interest match
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 

SELECT DISTINCT ?item ?itemLabel ?author ?authorLabel ?topic ?topicLabel WHERE {
  
  ?item mmdt:P2 mmd:Q2;
        mmdt:P5 ?author; # item has an author
        mmdt:P36 ?topic.
  
  ?author mmdt:P47 ?topic. # author has topic interest that is the same as topic
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
}}

== <!--T:9--> Visualizations ==


=== <!--T:709--> Bubble Chart: topics exctracted via Topic Modelling  ===

<!--T:709-->
Here, you can display the different topics present in the database in a Bubble Chart. 

{{SPARQL|query=#title:Topics referenced by topic modeling (Q21)
#do not delete following line. it looks like a comment but is important for the presentation of the results as a Bubble Chart.
#defaultView:BubbleChart
prefix mmd:<http://data.mimotext.uni-trier.de/entity/>
prefix mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 
prefix mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
prefix mmpr:<http://data.mimotext.uni-trier.de/prop/reference/>
SELECT ?themeLabel
        (count(*) as ?count) 
WHERE
{
    ?statement mmps:P36 ?theme. #statement has property 'about'
    ?statement prov:wasDerivedFrom ?refnode. #statement has a reference
    ?refnode   mmpr:P18 mmd:Q21. #reference statement uses 'P18'=stated in; stated in: Q21. use mmd:Q1 to see topics referenced by Bibliographie du genre romanesque français
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?themeLabel
ORDER BY ?name
}}

=== <!--T:709--> Line Chart: Average Token Count  ===

<!--T:709-->
This example shows hoe you can display information in different Charts. Here, you can see the average token count for each possible narrative form/year.

{{SPARQL|query=#title:average token count for each possible narrative form per year
#defaultView:LineChart
#replace LineChart with BarChart or ScatterChart if you prefer that presentation of your data
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 

SELECT ?year (avg(?tokencount) as ?avgtokencount) ?narrForm ?narrFormLabel
  WHERE{
    ?item mmdt:P9 ?publicationdate. # get publication date
    ?item mmdt:P40 ?tokencount. # get tokencount
    BIND(str(YEAR(?publicationdate)) as ?year). # extract year from pubdate
    ?item mmdt:P33 ?narrForm. # get narrative form
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
  }
GROUP BY ?narrForm ?year ?narrFormLabel
ORDER BY ?year
}}

=== <!--T:709--> Animated Bar Chart: Count of different Tone per Intention over the years ===

<!--T:709-->
This is a way to dynamically display information that is dependent on more than one variable. Here, the count of different tones per intention is shown. The Bar Chart is animated and changes as the years go on. 

{{SPARQL|query=#title:Count of different tones per intention and year (animated)
#defaultView:BarChart
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
SELECT ?intentionLabel (COUNT(?tone) AS ?toneCount) ?toneLabel ?year
WHERE{
  ?item mmdt:P2 mmd:Q2; # item is instance of literary work
        mmdt:P9 ?pubdate; # get the publication date
        mmdt:P38 ?tone; # get tone of work-item
        mmdt:P39 ?intention. # get intention of work-item
  ?tone rdfs:label ?toneLabel. # get the tone label
  ?intention rdfs:label ?intentionLabel. # get the intention label
  
  FILTER(LANG(?toneLabel) = "en"). # filter for language
  FILTER(LANG(?intentionLabel)="en"). # filter for language
  BIND(str(YEAR(?pubdate)) as ?year). # filter year of the publication date
}
GROUP BY ?year ?toneLabel ?intentionLabel 
}}

=== <!--T:709--> Area Chart: Publication Places  ===

<!--T:709-->
This example shows how to display information in an Area Chart. Here, the publication places with at least 5 instances per year are queried.

{{SPARQL|query=#title:Publication places that occur at least 5 times per year
#defaultView:AreaChart
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?date (count(?pubPlace) as ?count) ?pubPlaceLabel
WHERE{
  ?item mmdt:P2 mmd:Q2;
        mmdt:P9 ?date;
        mmdt:P10 ?pubPlace.
  ?pubPlace rdfs:label ?pubPlaceLabel.
  FILTER(LANG(?pubPlaceLabel) = "en").
}

GROUP BY ?date ?pubPlaceLabel
HAVING (count(?pubPlaceLabel) > 4)
}}

=== <!--T:709--> Tree: Authors, their novels and topics as expandable list  ===

<!--T:709-->
Here is an example on how to display information in an expandable list. The result will be a list of authors with the second level being their works, and the third being the topic labels of these works.

{{SPARQL|query=#title:Authors, their novels and thematic concepts
#defaultView:Tree
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/>

SELECT ?author ?authorLabel
?item ?itemLabel 
?topic ?topicLabel

WHERE{
  ?item mmdt:P2 mmd:Q2;  # item is instance of literary work
        mmdt:P36 ?topic; # item has a thematic concept
        mmdt:P33 ?narrForm; # item has a narrative form
        mmdt:P5 ?author.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }

}ORDER BY ?authorLabel
}}

=== <!--T:709--> Graph: Authors and their Membership in Organizations  ===

<!--T:709-->
This is how to display information in an intricate Graph. Here, the authors in the MiMoText database are queried and are connected to the societies they were members. To identify their membership, federated queries are used to extract that information from Wikidata. The organization should have at least two members that are also within the MiMoTextBase
{{SPARQL|query=#defaultView:Graph
#title:MiMoText authors that are members of an organisation having at least two members who are in the MiMoTextBase
PREFIX wd: <http://www.wikidata.org/entity/> #wikidata wd
PREFIX wdt: <http://www.wikidata.org/prop/direct/> #wikidata wdt
PREFIX mmd:<http://data.mimotext.uni-trier.de/entity/>
PREFIX mmdt:<http://data.mimotext.uni-trier.de/prop/direct/> 

SELECT ?author ?authorLabel ?img ?memberOf ?memberOfLabel 
WHERE {
  ?author mmdt:P11 mmd:Q11. 
  ?author mmdt:P13 ?WikiLink. #important for federated query!
  
  #federated query: extracts the organization the author is a member of and optionally their picture
  SERVICE <https://query.wikidata.org/sparql> {
    ?WikiLink wdt:P463 ?memberOf.
    ?memberOf rdfs:label ?memberOfLabel.
    OPTIONAL{?WikiLink wdt:P18 ?img}.
    FILTER(LANG(?memberOfLabel)="en").
  }   
        
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
  {
    #Count the number of authors for each organization and include only those with more than 1 author
    SELECT ?memberOf (COUNT(?author) as ?countmember) 
    WHERE {
      ?author mmdt:P11 mmd:Q11.
      ?author mmdt:P13 ?WikiLink.
      SERVICE <https://query.wikidata.org/sparql> {
        ?WikiLink wdt:P463 ?memberOf.
      }           
    }
  GROUP BY ?memberOf
  HAVING (?countmember > 1)
  }
}
}}

== <!--T:9--> Queries about secondary literature and references ==

=== <!--T:709--> List the labels of all secondary literature used in the MiMoTextBase  ===

<!--T:709-->
Here is an example on how to display information in an expandable list. The result will be a list of authors with the second level being their works, and the third being the topic labels of these works.

{{SPARQL|query=PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
PREFIX mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>

# List all labels of secondary literature that we have statements for

SELECT DISTINCT ?ref ?refLabel ?title WHERE {  
  ?statement prov:wasDerivedFrom ?refnode. # a statement was derived from the reference node.
  ?refnode mmpr:P18 ?ref. # the reference node as the property "stated in" (P18) any reference.
  ?ref mmdt:P2 mmd:Q3. # the reference is of instance scholary work
  ?ref mmdt:P4 ?title. 
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en".}
} 
}}

=== <!--T:709--> Count all references per secondary literature in either literary works or authors  ===

<!--T:709-->
Here we retrieve all quotations from secondary literature and count how many references each secondary literature has.

{{SPARQL|query=PREFIX mmpq: <http://data.mimotext.uni-trier.de/prop/qualifier/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
prefix mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
prefix mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>
prefix mmp: <http://data.mimotext.uni-trier.de/prop/>

# count all references per secondary literature in either literary works or authors

SELECT ?refLabel (COUNT(?refLabel) as ?count)  WHERE {
  ?item ?p ?statement. 
  ?statement prov:wasDerivedFrom ?refnode. # get the reference node
  ?refnode mmpr:P18 ?ref. # get the reference using "stated in"
  ?refnode mmpr:P42 ?quotation. # get the quotation via "quotation"
  ?ref mmdt:P2 mmd:Q3. # reference should be instance of scholarly work
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }

}
GROUP BY ?refLabel
ORDER BY DESC(?count)
}}

=== <!--T:709--> Get thematic concepts of literary work items that have at least 3 quotations from scholarly publications  ===

<!--T:709-->
This query retrieves novels and the counts of their associated P36 (about)-statements that are referenced at least three times by any scholarly work.

{{SPARQL|query=PREFIX mmpq: <http://data.mimotext.uni-trier.de/prop/qualifier/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
prefix mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
prefix mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>
prefix mmp: <http://data.mimotext.uni-trier.de/prop/>

# get all items that have the property about that have at least 3 quotations from scholarly publications

SELECT ?item ?itemLabel ?aboutLabel (COUNT(?quot) as ?count) WHERE {
  ?item mmdt:P2 mmd:Q2. # item is instance of literary work
  ?item mmp:P36 ?statement. # item has a statement group about (P36)
  ?statement mmps:P36 ?about. # get each statement for that statemet group 
  ?statement prov:wasDerivedFrom ?refnode. # the statement has a reference node
  ?refnode mmpr:P18 ?ref. # the references are references via stated in (P18)
  ?refnode mmpr:P42 ?quot. # there are quotations for the references (P42)
  ?ref mmdt:P2 mmd:Q3. # the reference is instance of scholarly work
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }

}
GROUP BY ?item ?itemLabel ?aboutLabel
HAVING (?count > 2) # filter those that have more than 2 quotations
ORDER BY DESC(?count)
}}

=== <!--T:709--> Get all references that mention "Voltaire" in the quotations on the about statements of literary works or the topic interest of authors  ===

<!--T:709-->
This query retrieves novels and the counts of their associated P36 (about)-statements that are referenced at least three times by any scholarly work.

{{SPARQL|query=PREFIX mmdref: <http://data.mimotext.uni-trier.de/reference/>
PREFIX mmpq: <http://data.mimotext.uni-trier.de/prop/qualifier/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
prefix mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
prefix mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>
prefix mmp: <http://data.mimotext.uni-trier.de/prop/>

# find all quotations that contain "Voltaire" and show all object that are contaning that quotation

SELECT DISTINCt ?item ?itemLabel ?quotation ?aboutLabel

WHERE{
  ?item ?p ?statement.
  VALUES ?value {mmps:P36 mmps:P47}
  ?statement ?value ?about.
  ?statement prov:wasDerivedFrom ?ref.
  ?ref mmpr:P18 ?refnode.
  ?ref mmpr:P42 ?quotation.
  FILTER(CONTAINS(?quotation, "Voltaire")).

  ?refnode mmdt:P2 mmd:Q3.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
}}


=== <!--T:709--> Show a Barchart of the temporal development of the topics written about in the secondary literature  ===

<!--T:709-->
This query retrieves novels and the counts of their associated P36 (about)-statements that are referenced at least three times by any scholarly work.

{{SPARQL|query=#defaultView:BarChart
PREFIX mmdref: <http://data.mimotext.uni-trier.de/reference/>
PREFIX mmpq: <http://data.mimotext.uni-trier.de/prop/qualifier/>
PREFIX mmdt: <http://data.mimotext.uni-trier.de/prop/direct/>
PREFIX mmd: <http://data.mimotext.uni-trier.de/entity/>
prefix mmps:<http://data.mimotext.uni-trier.de/prop/statement/>
prefix mmpr: <http://data.mimotext.uni-trier.de/prop/reference/>
prefix mmp: <http://data.mimotext.uni-trier.de/prop/>

# show barchart of topics of novels having more than 3 quotations over the year in the secondary literature

SELECT ?year (COUNT(?quotation) as ?yearcount)  ?aboutLabel 

WHERE{
  ?item ?p ?statement.
  ?statement mmps:P36 ?about.
  ?statement prov:wasDerivedFrom ?ref.
  ?ref mmpr:P18 ?refnode.
  ?ref mmpr:P42 ?quotation.
  ?refnode rdfs:label ?refnodeLabel.
  FILTER(LANG(?refnodeLabel) ="en").
  ?refnode mmdt:P2 mmd:Q3.
  ?refnode mmdt:P9 ?date. # get publication date from secondary literature
  BIND(STR(YEAR(?date)) as ?year). # extract the year and convert it to a string
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?year ?aboutLabel
HAVING(?yearcount > 3)
}}